編者按：以下是網(wǎng)友編寫的遙控解碼程序！一種用延時(shí)等待的解碼方法，比較容易理解，但缺點(diǎn)是占用CPU運(yùn)行時(shí)間，第二種方法用定時(shí)器和外中斷的解碼方法，初學(xué)不易理解，但優(yōu)點(diǎn)也很明顯，第二種方法如果能解決連發(fā)解碼就比較完美，更完善的紅外遙控解碼程序，請參考本站TOPAV-2008，TOP51-2005所配程序。
解碼方法一
;//單片機(jī)接收紅外解讀程序\\
;硬件結(jié)構(gòu)：8951，P0口數(shù)碼管段碼，P2.0-P2.3為位，P1為8個LED
;P3.2為紅外接收頭，P2.7蜂鳴器，晶振12M
;適用UPD6121 6122芯片接收
;---------------------------------------------------------
ORG 0000H
AJMP MAIN ;轉(zhuǎn)入主程序
ORG 0003H ;外部中斷P3.2腳INT0入口地址
AJMP INT ;轉(zhuǎn)入外部中斷服務(wù)子程序（解碼程序）
;以下為主程序進(jìn)行CPU中斷方式設(shè)置
MAIN: SETB EA ;打開CPU總中斷請求
SETB IT0 ;設(shè)定INT0的觸發(fā)方式為脈沖下降沿觸發(fā)
SETB EX0 ;打開INT0中斷請求
AJMP $
;以下為進(jìn)入P3.2腳外部中斷子程序，也就是解碼程序
INT: CLR EA ;暫時(shí)關(guān)閉CPU的所有中斷請求
MOV R6,#10
SB: ACALL YS1 ;調(diào)用882微秒延時(shí)子程序
JB P3.2,EXIT ;延時(shí)882微秒后判斷P3.2腳是否出現(xiàn)高
; 電平如果有就退出解碼程序
DJNZ R6, SB ;重復(fù)10次，目的是檢測在8820微秒內(nèi)
;如果出現(xiàn)高電平就退出解碼程序
;以上完成對遙控信號的9000微秒的初始低電平信號的識別。
JNB P3.2, $ ;等待高電平避開9毫秒低電平引導(dǎo)脈沖
ACALL YS2 ;延時(shí)4.74毫秒避開4.5毫秒的結(jié)果碼
MOV R1,#1AH ;設(shè)定1AH為起始RAM區(qū)
MOV R2,#4
;
PP: MOV R3,#8
JJJJ: JNB P3.2,$ ;等待地址碼第一位的高電平信號
LCALL YS1 ;高電平開始后用882微秒的時(shí)間尺去判斷信
;號此時(shí)的高低電平狀態(tài)
MOV C,P3.2 ;將P3.2引腳此時(shí)的電平狀態(tài)0或1存入C中
JNC UUU ;如果為0就跳轉(zhuǎn)到UUU
LCALL YS3
;
UUU: MOV A,@R1 ;將R1中地址的給A
RRC A ;將C中的值0或1移入A中的最低位
MOV @R1,A ;將A中的數(shù)暫時(shí)存放在R1中
DJNZ R3,JJJJ ;接收地址碼的高8位
INC R1 ;對R1中的值加1，換下一個RAM
DJNZ R2,PP ;接收完16位地址碼和8位數(shù)據(jù)碼和8位數(shù)據(jù)反
; 碼，存放在1AH/1BH/1CH/1DH的RAM中
MOV A,1CH ;比較數(shù)據(jù)碼和數(shù)據(jù)反碼是否正確?
CPL A
XRL A,1DH ;將1CH的值取反后和1DH比較 不同則無效丟棄，核對數(shù)據(jù)是否準(zhǔn)確
JNZ EXIT
MOV DPTR,#TAB ;表頭地址送指針
MOV A,1DH
ANL A,#0FH ;相與，得到低四位碼
MOVC A,@A+DPTR
MOV 1EH,A ;查表得表碼存入1EH
MOV A,1DH
SWAP A
ANL A,#0FH
MOVC A,@A+DPTR
MOV 1FH,A ;查表得高四位碼存入1F
MOV R7,#20H
DISP:
MOV P0,1FH ;送數(shù)碼管顯示
CLR P2.1
ACALL YS2
SETB P2.1
MOV P0,1EH
CLR P2.2
ACALL YS2
SETB P2.2
MOV P1,1DH ;將按鍵的鍵值通過P1口的8個LED顯示出來!
CLR P2.7 ;蜂鳴器鳴響－嘀嘀嘀－的聲音，表示解碼成功
LCALL YS2
SETB P2.7 ;蜂鳴器停止
DJNZ R7,DISP
EXIT: SETB EA ;允許中斷
RETI ;退出解碼子程序
YS1: MOV R4,#20 ;延時(shí)子程序1，精確延時(shí)882微秒
D1: MOV R5,#20
DJNZ R5,$
DJNZ R4,D1
RET
YS2: MOV R4,#10 ;延時(shí)子程序2，精確延時(shí)4740微秒
D2: MOV R5,#235
DJNZ R5,$
DJNZ R4,D2
RET
YS3: MOV R4,#2 ;延時(shí)程序3，精確延時(shí)1000微秒
D3:MOV R5,#248
DJNZ R5,$
DJNZ R4,D3
RET
TAB: DB 0C0H,0DEH,0A2H,8AH,9CH,89H,81H,0DAH,80H,88H,90H,85H,0E1H,86H,0A1H,0B1H;數(shù)據(jù)表，0-9-A-F
END
解碼方法二
你的解碼程序和我現(xiàn)在用的解碼程序大體是一樣的，我自己實(shí)際做了一下，發(fā)現(xiàn)按下遙控器，接收到紅外信號后，數(shù)碼管閃的厲害。我用的是6位動態(tài)數(shù)碼管。不知道你有沒有遇到這樣的情況？
分析解碼程序，感覺是中斷的時(shí)間太長了，數(shù)碼管當(dāng)然會閃了。如果把數(shù)碼管用定時(shí)器刷新的話，又存在定時(shí)中斷和外中斷的優(yōu)先級問題，好難解決啊。
我初步有個想法。就是用定時(shí)器計(jì)算兩次外中斷間隔的時(shí)間。以此來確定是連發(fā)碼，數(shù)據(jù)“0”，數(shù)據(jù)“1”。不知道這個想法可否行的通。這幾天沒有時(shí)間試，因?yàn)閺V州有個電子產(chǎn)品交易會，我要趕著做樣機(jī)。過了幾天我有空了在仔細(xì)的做一遍。把結(jié)果告訴大家。
不用連續(xù)解碼，只需在中斷時(shí)讀取定時(shí)器的時(shí)間，然后判斷是0或者1就可以了，實(shí)際測試已經(jīng)OK了，謝謝兩位的熱心幫助。
為了這個程序，弄了兩天的時(shí)間，飯都吃不好，現(xiàn)在弄通了，感覺真的很好。
我現(xiàn)在用6個數(shù)碼管顯示遙控器的用戶碼，用戶反碼，按鍵碼，無論怎么按遙控器，數(shù)碼管都不會閃的。
樓上的，我是這樣解決閃爍問題的，用顯示子程序計(jì)算出適當(dāng)次數(shù)代替延時(shí)YS1 YS2 YS3子程序
;======================================================================================
;紅外解碼程序
;晶體:11.0592M
;日期:2005-10-14
;功能:將6122發(fā)射IC發(fā)射的紅外碼解碼，儲存在CODE1--CODE4中,并用6個數(shù)碼管顯示用戶碼,用戶反碼，按鍵碼
;======================================================================================
ORG 0000H
AJMP MAIN
ORG 0003H
AJMP REMOT
ORG 000BH
AJMP TIME0
;------------------------------------------------------
IR BIT P3.2
CODE1 EQU 30H ;遙控用戶碼
CODE2 EQU 31H ;遙控用戶反碼
CODE3 EQU 32H ;按鍵碼
CODE4 EQU 33H ;按鍵反碼
TIME1_REMOT EQU 34H ;每次接收的碼BIT數(shù)
TIME2_REMOT EQU 35H ;允許重碼次數(shù)
TIME3_REMOT EQU 36H ;按鍵數(shù)目存放
;---------------------------------------------------------
DIG1 BIT P2.1;第一位數(shù)碼管選通
DIG2 BIT P2.5;第二位數(shù)碼管選通
DIG3 BIT P2.0;第三位數(shù)碼管選通
DIG4 BIT P2.4;第四位數(shù)碼管選通
DIG5 BIT P2.6;第五位數(shù)碼管選通
DIG6 BIT P2.3;第六位數(shù)碼管選通
;----------------------------------------
D1 EQU 40H
D2 EQU 41H
D3 EQU 42H
D4 EQU 43H
D5 EQU 44H
D6 EQU 45H
ORG 0030H
;=============================初始化===============================
MAIN:
SETB EA ;開總中斷
MOV TMOD,#1H ;定時(shí)器0工作于方式1
SETB ET0 ;啟動定時(shí)器0
SETB TR0
MOV TH0,#0 ;預(yù)置數(shù)0
MOV TL0,#0
SETB EX0 ;開外中斷0
SETB IT0
MOV TIME1_REMOT,#32;接收的碼一共32BIT:4*8
CLR P1.0
MOV D1,#10H
MOV D2,#10H
MOV D3,#10H
MOV D4,#10H
MOV D5,#10H
MOV D6,#10H
;============================初始化完畢============================
;=============================主程序==============================
LOOP:
; ACALL FENLI
ACALL DIG
AJMP LOOP
;=============================主程序完畢==========================
;=============================紅外解碼中斷程序=========================
;=============================================
;以下為紅外中斷解碼程序
;接收頭引腳P3.2
;按鍵反碼: CODE1
;按鍵碼:CODE2
;用戶反碼: CODE3
;用戶碼:CODE4
;接收碼的BIT數(shù):TIME1_REMOT
;重碼次數(shù):TIME3_REMOT;
;入口函數(shù):
;出口函數(shù):R0---按鍵反碼 R1----按鍵碼 R2---用戶反碼 R3----用戶碼 R4---按鍵標(biāo)準(zhǔn)鍵值
;=============================================
REMOT:
CLR EA ;關(guān)總中斷
PUSH ACC
PUSH PSW
PUSH DPH
PUSH DPL
CLR P1.7
;-----------------判斷定時(shí)器運(yùn)行時(shí)間是否大于12.288MS-----------------
MOV A,TH0 ;讀入此時(shí)TH0,判斷是否大于設(shè)定的數(shù)
CLR C ;清除C避免誤判
SUBB A,#2CH ;11.0592-2C 12M-30 6M-18 4M-10 24M-60
JC REMOT1 ;小于12.220往下判斷
AJMP EXIT_REMOT1 ;大于2BFF*1.085=12.220MS則退出
;-----------------判斷定時(shí)器運(yùn)行時(shí)間是否小于0.768MS------------------
REMOT1:
MOV A,TH0
CLR C
SUBB A,#23H ;11.0592-2 12M-3 6M*-1 4M-1 24M-6
JNC REMOT2
AJMP EXIT_REMOT ;小于0.768作誤碼,退出
;------------------判斷定時(shí)器運(yùn)行時(shí)間是否小于2MS---------------------
REMOT2:
MOV A,TH0
CLR C
SUBB A,#7H ;11.0592-7 12M-7 6M-3 4M-2 24M-0FH
JC REMOT4
AJMP REMOT3 ;小于2MS,做數(shù)據(jù):"0:處理
;-----------------判斷定時(shí)器運(yùn)行時(shí)間是否小于11.5MS-------------------
REMOT3:
MOV A,TH0
CLR C
SUBB A,#29H ;11.0592-29 12M-2C 6M-16 4M-0EH 24M-59
JC REMOT5 ;小于11.5MS,做數(shù)據(jù)"1"處理
AJMP REMOT6 ;否則作重碼處理
;----------------數(shù)據(jù)"0"----------------------
REMOT4:
CLR C
AJMP REMOT7
;----------------數(shù)據(jù)"1"--------------------
REMOT5:
SETB C
AJMP REMOT7
;----------------重碼------------------------
REMOT6:
DJNZ TIME3_REMOT,EXIT_REMOT
MOV TIME3_REMOT,#2
AJMP EXIT_REMOT1
;---------------儲存數(shù)據(jù)--------------------
REMOT7:
MOV A,CODE1
RRC A
MOV CODE1,A
MOV A,CODE2
RRC A
MOV CODE2,A
MOV A,CODE3
RRC A
MOV CODE3,A
MOV A,CODE4
RRC A
MOV CODE4,A
DJNZ TIME1_REMOT,EXIT_REMOT
MOV TIME1_REMOT,#32;判斷是否接收完32位,
MOV R0,CODE1
MOV R1,CODE2
MOV R2,CODE3
MOV R3,CODE4
AJMP BIJIAO ;此處設(shè)置斷點(diǎn),R0--按鍵反碼
;R1---按鍵碼
;R2---用戶反碼
;R3---用戶碼
;---------------用戶碼判斷-------------------------
BIJIAO:
; MOV A,CODE4
; CJNE A,#10H,EXIT_REMOT
; MOV A,CODE3
; CJNE A,#0EFH,EXIT_REMOT
;---------------按鍵碼判斷-----------------------
MOV A,CODE2
CPL A
XRL A,CODE1
JNZ EXIT_REMOT
ACALL FENLI
AJMP EXIT_REMOT1
;--------------將按鍵碼轉(zhuǎn)換為標(biāo)準(zhǔn)的碼值-----------
OK_REMOT:
MOV TIME3_REMOT,#15 ;按鍵數(shù):15個按鍵
MOV R4 DPTR,#TAB_REMOT ;指針指向按鍵碼值表
OK_REMOT1:
MOV A,TIME3_REMOT ;將碼值表第一個數(shù)與CODE2比較
MOVC A,@A+DPTR
XRL A,CODE2
JZ OK_REMOT2 ;相同，已經(jīng)找到，跳轉(zhuǎn)出口
DJNZ TIME3_REMOT,OK_REMOT1;不同,未找到,取下一個按鍵碼值比較,直到相同為止
AJMP EXIT_REMOT1 ;已經(jīng)找完碼值表,未找到匹配數(shù)據(jù)，退出
;-------------
OK_REMOT2:
MOV R4,TIME3_REMOT ;將標(biāo)準(zhǔn)碼值存入R4
AJMP EXIT_REMOT
;--------------------按鍵碼值表------------------------
TAB_REMOT:
DB 0H
;SETB
;ST.BY-INPUT-REST
DB 04H,02H,06H
;
;FR- MAST+ FR+
DB 0EH,07H,00H
; ;SUB- MUTE SUB+
DB 10H,0FH,12H
; ;CEN- MAST+ CEN+
DB 13H,03H,0AH
; ;SUR- SET75 SUR+
DB 11H,08H,01H
;---------------解碼中斷退出程序--------------------
EXIT_REMOT1: ;異常退出
MOV TIME1_REMOT,#32
EXIT_REMOT: ;正常退出
MOV TH0,#0 ;重設(shè)定時(shí)器0
MOV TL0,#0
SETB EA
SETB TR0 ;開中斷
; SETB EX0
CLR IE0 ;清外中斷標(biāo)志,避免反復(fù)中斷
POP DPL
POP DPH
POP PSW
POP ACC ;出棧
SETB P1.7
RETI
;=========================紅外解碼中斷程序完畢====================
;=========================定時(shí)中斷程序============================
;============================================================
;以下為定時(shí)器中斷程序
;功能:每120MS清除遙控用戶碼緩存
;入口函數(shù):
;出口函數(shù):
;============================================================
TIME0:
CLR EA
MOV TH0,#0
MOV TL0,#0
MOV CODE1,#0
MOV CODE2,#0
MOV CODE3,#0
MOV CODE4,#0
SETB EA
RETI
;==============================================================
;=======================以下為數(shù)碼管顯示數(shù)分離子程序================
; ;功能:將遙控器的用戶碼,用戶反碼，按鍵碼,的十位與個位分離
;入口函數(shù):R3--用戶碼,R2--用戶反碼,R1---按鍵碼
;出口函數(shù):D1-用戶碼十位,D2--用戶個位,D3--用戶反碼十位,D4---用戶反碼個位,
; ;D5---按鍵碼十位,D6---按鍵碼個位
;----------------------------------------------------------
FENLI:
MOV A,R3 ;分離用戶反碼
MOV B,#16
DIV AB
MOV D1,A
MOV D2,B
MOV A,R2 ;分離用戶碼
MOV B,#16
DIV AB
MOV D3,A
MOV D4,B
MOV A,R1 ;分離按鍵碼
MOV B,#16
DIV AB
MOV D5,A
MOV D6,B
RET
;-----------分離完畢-------------------------
;===================以下為數(shù)碼管顯示子程序=======================
;入口函數(shù):D1---D6
;--------------------------------------------------------------
DIG:
MOV DPTR,#TAB_DIG ;顯示用戶反碼十位
MOV A,D1
MOVC A,@A+DPTR
MOV P2,#0FFH
MOV P0,A
CLR DIG1
ACALL YS2MS
MOV DPTR,#TAB_DIG ;顯示用戶反碼個位
MOV A,D2
MOVC A,@A+DPTR
MOV P2,#0FFH
MOV P0,A
CLR DIG2
ACALL YS2MS
MOV DPTR,#TAB_DIG ;顯示用戶碼十位
MOV A,D3
MOVC A,@A+DPTR
MOV P2,#0FFH
MOV P0,A
CLR DIG3
ACALL YS2MS
MOV DPTR,#TAB_DIG ;顯示用戶碼個位
MOV A,D4
MOVC A,@A+DPTR
MOV P2,#0FFH
MOV P0,A
CLR DIG4
ACALL YS2MS
MOV DPTR,#TAB_DIG ;顯示按鍵碼十位
MOV A,D5 MOVC A,@A+DPTR MOV P2,#0FFH MOV P0,A CLR DIG5 ACALL YS2MS MOV DPTR,#TAB_DIG ;顯示按鍵碼個位 MOV A,D6
MOVC A,@A+DPTR
MOV P2,#0FFH
MOV P0,A
CLR DIG6
ACALL YS2MS
;---------------------------顯示完畢-----------------------------------
RET
;------------------------------數(shù)碼管段碼表------------------------------------
TAB_DIG: ;0 1 2 3 4 5 6 7 8 9 A B C D E F 全亮 消隱
DB 5H,0B7H,51H,31H,0A3H,29H,9H,37H,1H,21H,3H,89H,4DH,4DH,49H,4BH,0h,0ffh
;------------------------------延時(shí)-------------------------------------------
YS2MS:
MOV R7,#15
DEL1:MOV R6,#100
DJNZ R6,$
DJNZ R7,DEL1
RET
END |
|
66821730(技術(shù)支持)
