|
摘要 在無線遙控領(lǐng)域，PT2262/2272是目前最常用的芯片之一，但由于芯片要求配對使用，在很大程度上影響了該芯片的使用，筆者從PT2262波形特征入手，結(jié)合應(yīng)用實(shí)際，提出軟件解碼的方法和具體措施。 關(guān)鍵詞 PT2262 軟件解碼 電平 一、概述 PT2262/2272是一種CMOS工藝制造的低功耗低價(jià)位通用編解碼電路，是目前在無線通訊電路中作地址編碼識別最常用的芯片之一。PT2262/2272最多可有12位(A0-A11)三態(tài)地址端管腳(懸空,接高電平,接低電平),任意組合可提供531441地址碼,PT2262最多可有6位(D0-D5)數(shù)據(jù)端管腳,設(shè)定的地址碼和數(shù)據(jù)碼從17腳串行輸出。 PT2262/2272必須用相同地址碼配對使用，當(dāng)需要增加一個(gè)通訊機(jī)時(shí)，用戶不得不求助于技術(shù)人員或廠家來設(shè)置相同地址碼，客戶自己設(shè)置相對比較麻煩，尤其對不懂電子的人來說。隨著人們對操作的要求越來越高，PT2262/2272的這種配對使用嚴(yán)重制約著使用的方便性，人們不斷地要求使用一種無須請教專業(yè)人士，無須使用特殊工具，任何人都可以操作的方便的手段來彌補(bǔ)PT2262/2272的缺陷，這就是PT2262軟件解碼。 二、解碼原理 
上面是PT2262的一段波形，可以看到一組一組的字碼，每組字碼之間有同步碼隔開，所以我們?nèi)绻脝纹瑱C(jī)軟件解碼時(shí)，程序只要判斷出同步碼，然后對后面的字碼進(jìn)行脈沖寬度識別即可。 2262每次發(fā)射時(shí)至少發(fā)射4組字碼，2272只有在連續(xù)兩次檢測到相同的地址碼加數(shù)據(jù)碼時(shí)才會把數(shù)據(jù)碼中的“1”驅(qū)動相應(yīng)的數(shù)據(jù)輸出端為高電平和驅(qū)動VT端同步為高電平。因?yàn)闊o線發(fā)射的特點(diǎn)，第一組字碼非常容易受零電平干擾，往往會產(chǎn)生誤碼，所以程序可以丟棄處理。 下面我們來仔細(xì)看一下PT2262的波形特征： 振蕩頻率f=2*1000*16/Rosc(kΩ) kHz 其中Rosc為振蕩電阻 這里我們選用的是一種比較常用的頻率f≈10 kHz, Rosc=3.3MΩ(以下同)。 下圖是振蕩頻率與碼位波形的對應(yīng)關(guān)系： 
同步碼頭波形： 
PT2262有三種編碼：0，1，和懸空(表示為f)。 
有了以上具體的波形，我們就可以進(jìn)行軟件解碼了。T2262每次至少發(fā)送4次編碼，首先我們可以通過檢測11ms寬度的同步碼頭，有碼頭才開始進(jìn)行編碼解碼，無碼頭則繼續(xù)等待。當(dāng)收到碼頭時(shí)，還要檢測是否已經(jīng)收到過碼頭，若無，則丟棄第一次編碼的信號，以防止誤碼。 從編碼圖中可以看出，每一位碼字都是從低電平開始到高電平，到低電平，再到高電平。為了檢測方便，在接收端我們把編碼信號進(jìn)行了180°倒相，使碼位開始的上升沿轉(zhuǎn)化為下降沿，這樣當(dāng)我們使用MCS51系列單片機(jī)解碼時(shí)可使用中斷方式及時(shí)截獲編碼。從編碼圖中還可以看出，每一位碼字都可以分成兩段，我們以每段中的電平寬度來描述碼位： |
碼位 | 第一段 | 第二段 | 數(shù)值表示 | 反碼表示 | 0 | 窄 | 窄 | 00 | 11 | 1 | 寬 | 寬 | 11 | 00 | f | 窄 | 寬 | 01 | 10 | 無效碼 | 寬 | 窄 | 10 | 01 | 軟件解碼方法1(反碼)：
從第一個(gè)下降沿開始延時(shí)700us左右，檢測電平高低，記為A1，再檢測第二個(gè)下降沿，延時(shí)700us左右，檢測電平高低，記為A2，這樣一個(gè)碼位就可以譯出來了，連續(xù)檢測12個(gè)碼位。
軟件解碼方法2(反碼)：
從第一個(gè)下降沿開始記時(shí)，并不斷檢測電平變化，一有電平變化，立即記錄電平寬度B1，再繼續(xù)記時(shí)直至出現(xiàn)第二個(gè)下降沿，記錄兩個(gè)下降沿的間隔B2，重復(fù)以上步驟，得到B3，B4，判斷B1，B2，B3，B4是否在各自允許的誤差范圍內(nèi)，是則保存B1，B3，譯出一個(gè)碼位，否則認(rèn)為誤碼，丟棄。連續(xù)正確檢測12個(gè)碼位。
兩種解碼方式各有優(yōu)缺點(diǎn)如下：
解碼方式 | 優(yōu)點(diǎn) | 缺點(diǎn) | 1 | 程序簡單，CPU開銷少 | 解碼精度差 | 2 | 程序復(fù)雜，CPU開銷大 | 解碼精度較高 | 為了獲得較高的解碼精度，我們推薦使用方法2，以避免大量的干擾信號的誤解碼。
三、參考解碼軟件
說明：ADD1，ADD2中為8位地址，DAT0中為4位數(shù)據(jù)
REMOTE: CLR TR2 ;探頭信號檢測子程序
CLR RECEIVE ;
MOV DETE_LOOP,#12 ;接收12位編碼
REMO0: CLR DETE_T_OVER ;
MOV TH2,#0FEH ;測第1位電平寬度
MOV TL2,#041H ;
SETB TR2 ;
REMO1: JB REM,REMO2 ;等待出現(xiàn)高電平
JB DETE_T_OVER,REMO3 ;限時(shí)1500us,超時(shí)則認(rèn)為誤碼
AJMP REMO1 ;
REMO2: MOV A,TH2 ;測低電平寬度,0FF為寬脈沖，0FE為窄脈沖
CJNE A,#0FFH,REMO4 ;
MOV A,TL2 ;
CLR C ;
CJNE A,#098H,$+3 ;
JNC REMO3 ;電平過寬(超過1150us)，退出
CLR C ;
CJNE A,#020H,$+3 ;
JC REMO3 ;電平過窄(小于780us)，退出
SETB C ;
AJMP REMO5 ;
REMO3: AJMP REMOTE_END ;
REMO4: CJNE A,#0FEH,REMO3 ;
MOV A,TL2 ;
CLR C ;
CJNE A,#0C7H,$+3 ;
JNC REMO3 ;電平過寬(超過450us)，退出
CLR C ;
CJNE A,#060H,$+3 ;
JC REMO3 ;電平過窄(小于210us)，退出
CLR C ;
REMO5: MOV A,DAT0 ;存儲電平值
RLC A ;
MOV DAT0,A ;
MOV A,ADD1 ;
RLC A ;
MOV ADD1,A ;
REMO6: JNB REM,REMO7 ;等待出現(xiàn)低電平
JB DETE_T_OVER,REMO3 ;脈沖下降沿間隔限時(shí)1500us,超時(shí)則認(rèn)為誤碼
AJMP REMO6 ;
REMO7: CLR TR2 ;
CLR DETE_T_OVER ;
MOV A,TH2 ;
CJNE A,#0FFH,REM13 ;脈沖間隔過小
MOV A,TL2 ;
CLR C ;
CJNE A,#050H,$+3 ;
JC REM13 ;電平過窄(小于1200us)，退出
MOV TH2,#0FEH ;測第2位電平寬度
MOV TL2,#041H ;
SETB TR2 ;
REM11: JB REM,REM12 ;等待出現(xiàn)高電平
JB DETE_T_OVER,REM13 ;限時(shí)1500us,超時(shí)則認(rèn)為誤碼
AJMP REM11 ;
REM12: MOV A,TH2 ;測低電平寬度,0FE為寬脈沖，0FF為窄脈沖
CJNE A,#0FFH,REM14 ;
MOV A,TL2 ;
CLR C ;
CJNE A,#098H,$+3 ;
JNC REM13 ;電平過寬(超過1100us)，退出
CLR C ;
CJNE A,#020H,$+3 ;
JC REM13 ;電平過窄(小于1000us)，退出
SETB C ;
AJMP REM15 ;
REM13: AJMP REMOTE_END ;
REM14: CJNE A,#0FEH,REM13 ;
MOV A,TL2 ;
CLR C ;
CJNE A,#0C7H,$+3 ;
JNC REM13 ;電平過寬(超過450us)，退出
CLR C ;
CJNE A,#060H,$+3 ;
JC REM13 ;電平過窄(小于210us)，退出
CLR C ;
REM15: MOV A,TEMP ;存儲電平值
RLC A ;
MOV TEMP,A ;
MOV A,ADD2 ;
RLC A ;
MOV ADD2,A ;
REM16: JNB REM,REM18 ;等待出現(xiàn)低電平
JB DETE_T_OVER,REM13 ;脈沖下降沿間隔限時(shí)1500us,超時(shí)則認(rèn)為誤碼
AJMP REM16 ;
REM17: AJMP REMO0
REM18: CLR TR2 ;
CLR DETE_T_OVER ;
MOV A,TH2
CJNE A,#0FFH,REM13 ;脈沖間隔過小
MOV A,TL2 ;
CLR C ;
CJNE A,#050H,$+3 ;
JC REM13 ;電平過窄(小于1200us)，退出
DJNZ DETE_LOOP,REM17 ;
REM19: MOV DETE_LOOP,#4 ;把接收的編碼左移4位
REM20: CLR C ;將8位密碼放在同一字節(jié)上
MOV A,DAT0 ;
RLC A ;
MOV DAT0,A ;
MOV A,ADD1 ;
RLC A ;
MOV ADD1,A ;
CLR C ;
MOV A,TEMP ;
RLC A ;
MOV TEMP,A ;
MOV A,ADD2 ;
RLC A ;
MOV ADD2,A ;
DJNZ DETE_LOOP,REM20 ;
;把4 位數(shù)據(jù)編碼由高4 位移到低4 位上 ;
MOV A,DAT0 ;
SWAP A ;
MOV DAT0,A ;
MOV A,TEMP ;
SWAP A ;
MOV TEMP,A ;
ANL DAT0,#0FH ;
SETB RECEIVE ;
REMOTE_END: ;
CLR TR2
CLR REMOTING ;
RET ;
四、硬件抗干擾
在無線通訊中使用單片機(jī)會對通訊系統(tǒng)造成嚴(yán)重的干擾，相信許多技術(shù)人員一定有過同樣的苦惱。如果硬件設(shè)計(jì)不當(dāng)，會造成原先硬件解碼時(shí)通訊距離為200米，而用軟件解碼后可能只有十幾米，因此解決硬件抗干擾問題在很大程度上可減少軟件解碼的誤碼率。
1、收發(fā)模塊：早期常用的頻率為47MHz，在這種頻率下，很難有好的解決方法；建議采用目前國家允許無線遙控使用的頻率315 MHz；
2、單片機(jī)振蕩頻率：大量的MCS51教材中推薦大家使用的是12 MHz及11.0592 MHz的晶體，這些晶體在一般場合使用沒有問題，但在此卻不可以，它們在300 MHz左右仍然能夠產(chǎn)生較大的干擾，為解決單片機(jī)運(yùn)行速度與電磁干擾的矛盾，建議采用頻率為4 MHz或3.58 MHz的晶體。
3、隔離：為了有效抑制單片機(jī)對接收模塊的電磁干擾，建議采用①電源隔離；②端口隔離；端口隔離可采用三極管或比較器。實(shí)踐表明，采用隔離的效果非常明顯。
五、結(jié)束語
PT2262的軟件解碼在實(shí)際應(yīng)用中有較好的用武之地。采用軟件解碼的系統(tǒng)，廠家再也無須對收發(fā)設(shè)備進(jìn)行配套，以利于生產(chǎn)于保管；對客戶來說，使用軟件解碼無須求助，廠家只須再軟件中加入自動學(xué)習(xí)功能，用戶可自行使用該功能，只須輕按學(xué)習(xí)鍵即可學(xué)習(xí)新的通訊設(shè)備，如遙控器等。
目前，該軟件解碼已經(jīng)在某無線報(bào)警設(shè)備中采用，客戶反映使用簡便，效果良好。
參考：1、PT2262 PT2272 和P87LPC764 單片機(jī)的接口設(shè)計(jì)（廣州周立功單片機(jī)）；
站資料/PT2262編碼芯片的軟件解碼-%20無憂電子開發(fā)網(wǎng)-技術(shù)文章.files/1119517591.jpg)
站資料/PT2262編碼芯片的軟件解碼-%20無憂電子開發(fā)網(wǎng)-技術(shù)文章.files/1119517629.jpg)
站資料/PT2262編碼芯片的軟件解碼-%20無憂電子開發(fā)網(wǎng)-技術(shù)文章.files/1119517698.jpg)
站資料/PT2262編碼芯片的軟件解碼-%20無憂電子開發(fā)網(wǎng)-技術(shù)文章.files/1119517756.jpg)
66821730(技術(shù)支持)
