;********增量式PID控制算法程序***********
;T、TD、TI、KP依次從30H，33H，36H，39H開始。
;A，B，C的值依次存在BLOCK1，BLOCK2，BLOCK3的地址里
; 這里R(k)給的是定值
;
ORG 0000H
BLOCK1 EQU 43H ;A,B ,C
BLOCK2 EQU 46H
BLOCK3 EQU 49H
UK EQU 4CH ;存結(jié)果UK
RK EQU 50H
EK EQU 53H ;存放偏差值E(k)的始址
EK1 EQU 56H ;存放E(k-1)的始址
EK2 EQU 59H ;存放E(k-2)的始址
CK EQU 5CH ;采樣數(shù)據(jù)始址
BUFF EQU 60H ;暫存區(qū)
BUFF1 EQU 63H
BUFF2 EQU 66H
REC EQU 69H
TEST:
MOV RK,#01H ;常數(shù)Rk的BCD碼浮點數(shù)
MOV RK+1,#12H ;1.25
MOV RK+2,#50H
MOV 3CH,#01H ;常數(shù)1的BCD碼浮點數(shù)
MOV 3DH,#10H
MOV 3EH,#00H
MOV 40H,#01H ;常數(shù)2的BCD碼浮點數(shù)
MOV 41H,#20H
MOV 42H,#00H
MOV 30H,#01H ;T的BCD 碼浮點數(shù)
MOV 31H,#23H ;2.34
MOV 32H,#40H
MOV 33H,#01H ;Td的BCD碼浮點數(shù)
MOV 34H,#35H ;3.54
MOV 35H,#40H
MOV 36H,#01H ;Ti的BCD碼浮點數(shù)
MOV 37H,#11H ;1.12
MOV 38H,#20H
MOV 39H,#01H ;Kp的BCD碼浮點數(shù)
MOV 3AH,#12H ;1.25
MOV 3BH,#50H
MOV R0,#RK ;指向ＢＣＤ碼浮點操作數(shù)
LCALL BTOF ;將其轉(zhuǎn)換成二進制浮點操作數(shù)
MOV R0,#3CH
LCALL BTOF
MOV R0,#40H
LCALL BTOF
MOV R0,#39H
LCALL BTOF
MOV R0,#36H ;指向ＢＣＤ碼浮點操作數(shù)Ti
LCALL BTOF ;將其轉(zhuǎn)換成二進制浮點操作數(shù)
MOV R0,#33H ;指向ＢＣＤ碼浮點操作數(shù)Td
LCALL BTOF ;將其轉(zhuǎn)換成二進制浮點操作數(shù)
MOV R0,#30H ;指向ＢＣＤ碼浮點操作數(shù)T
LCALL BTOF ;將其轉(zhuǎn)換成二進制浮點操作數(shù)
MOV R1, #BUFF1 ;保存30H中的值 即T值
LCALL FMOVR0
MOV R1, #36H ;計算A值(1+T/Ti+Td/T).Kp
LCALL FDIV
MOV R1,#3CH ;常數(shù)1
LCALL FADD
MOV R0,#33H ;保存33H中的值
MOV R1,#BUFF
LCALL FMOVR0
MOV R1,#BUFF1
LCALL FDIV
MOV R1,#30H ;30H里存的是T/Ti+1
LCALL FADD
MOV R1,#39H
LCALL FMUL
MOV R1 ,#BLOCK1 ;將結(jié)果保存在BLOCK1中
LCALL FMOVR0
MOV R1,#BUFF1 ;30H恢復(fù)原值
MOV R0,#30H
LCALL FMOV
MOV R1,#BUFF ;33H恢復(fù)原值
MOV R0,#33H
LCALL FMOV
MOV R0,#40H ;計算B的值Kp.(1+2.Td/T)
MOV R1,#33H
LCALL FMUL
MOV R1,#30H
LCALL FDIV
MOV R1,#3CH
LCALL FADD
MOV R1,#39H
LCALL FMUL
MOV R1,#BLOCK2 ;保存B值到BLOCK2中
LCALL FMOVR0
MOV R0,#39H ;計算C的值Kp.Td/T
MOV R1,#33H
LCALL FMUL
MOV R1,#30H
LCALL FDIV
MOV R1,#BLOCK3 ;保存C值到BLOCK3中
LCALL FMOVR0
MOV R0,#EK1 ;將EK1，EK2設(shè)初值0
LCALL FCLR
MOV R0,#EK2
LCALL FCLR
MOV REC,#03H ;設(shè)置采樣次數(shù)
LOOP: MOV CK,#7eH ;采樣數(shù)據(jù)暫時給了一個定值
MOV CK+1,#21H ;0.002112
MOV CK+2,#12H
MOV R0,#CK
LCALL BTOF
MOV R0,#RK ;保存R（k）中的值
MOV R1,#BUFF
LCALL FMOVR0
MOV R1,#CK
LCALL FSUB ;計算R(k)-C(k)的值送給E（k）
MOV R1,#EK
LCALL FMOVR0
MOV R1,#BUFF ;恢復(fù)RK的值 釋放BUFF
MOV R0,#RK
LCALL FMOV
MOV R0,#BLOCK2 ;將B.e(k-1)的值暫存在BUFF1中
MOV R1,#BUFF ;保存B
LCALL FMOVR0
MOV R1,#EK1
LCALL FMUL
MOV R1,#BUFF1
LCALL FMOVR0
MOV R1,#BUFF ;恢復(fù)B釋放BUFF
LCALL FMOV
MOV R0,#BLOCK3 ;將C.e(K-2)的值暫存在BUFF2中
MOV R1,#BUFF ;保存C
LCALL FMOVR0
MOV R1,#EK2
LCALL FMUL
MOV R1,#BUFF2
LCALL FMOVR0
MOV R1,#BUFF ;恢復(fù)C釋放BUFF
LCALL FMOV
MOV R0,#BLOCK1 ;A.E(k)
MOV R1,#BUFF
LCALL FMOVR0
MOV R1,#EK
LCALL FMUL
MOV R1,#BUFF1 ;計算Uk值A(chǔ).E(k)-B.E(k-1)+C.E(k-2)
LCALL FSUB
MOV R1,#BUFF2
LCALL FADD
MOV R1,#UK ;保存結(jié)果到UK中
LCALL FMOVR0
MOV R1,#BUFF ;恢復(fù)A 釋放BUFF
LCALL FMOV
MOV R0,#UK ;UK轉(zhuǎn)換成BCD碼浮點數(shù)輸出
LCALL FTOB
MOV R1,#EK1 ;將E(k-1)-->E(k-2),E(k)-->E(k-1)
MOV R0,#EK2
LCALL FMOV
MOV R1,#EK
MOV R0,#EK1
LCALL FMOV
LCALL DELAY ;等待采樣時刻
DJNZ REC,NEXT1
SJMP $
NEXT1: LJMP LOOP
DELAY: MOV R7,#02H
DELAY1: MOV R6,#0FFH
DELAY2: DJNZ R6,DELAY2
DJNZ R7,DELAY1
RET
; （１） 標(biāo)號： ＦＳＤＴ 功能：浮點數(shù)格式化
;入口條件：待格式化浮點操作數(shù)在[R0]中。
;出口信息：已格式化浮點操作數(shù)仍在[R0]中。
;影響資源：PSW、A、R2、R3、R4、位1FH 堆棧需求： ６字節(jié)
FSDT: LCALL MVR0 ;將待格式化操作數(shù)傳送到第一工作區(qū)中
LCALL RLN ;通過左規(guī)完成格式化
LJMP MOV0 ;將已格式化浮點操作數(shù)傳回到[R0]中
; （２） 標(biāo)號： ＦＡＤＤ 功能：浮點數(shù)加法
;入口條件：被加數(shù)在[R0]中，加數(shù)在[R1]中。
;出口信息：OV=0時，和仍在[R0]中，OV=1時，溢出。
;;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： ６字節(jié)
FADD: CLR F0 ;設(shè)立加法標(biāo)志
SJMP AS ;計算代數(shù)和
; （３） 標(biāo)號： ＦＳＵＢ 功能：浮點數(shù)減法
;入口條件：被減數(shù)在[R0]中，減數(shù)在[R1]中。
;出口信息：OV=0時，差仍在[R0]中，OV=1時，溢出。
;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：６字節(jié)
FSUB: SETB F0 ;設(shè)立減法標(biāo)志
AS: LCALL MVR1 ;計算代數(shù)和。先將[R1]傳送到第二工作區(qū)
MOV C,F0 ;用加減標(biāo)志來校正第二操作數(shù)的有效符號
CLR A ; ********？？？應(yīng)加的一條語句
RRC A
XRL A,@R1
MOV C,ACC.7
ASN: MOV 1EH,C ;將第二操作數(shù)的有效符號存入位1EH中
XRL A,@R0 ;與第一操作數(shù)的符號比較
RLC A
MOV F0,C ;保存比較結(jié)果
LCALL MVR0 ;將[R0]傳送到第一工作區(qū)中
LCALL AS1 ;在工作寄存器中完成代數(shù)運算
MOV0: INC R0 ;將結(jié)果傳回到[R0]中的子程序入口
INC R0
MOV A,R4 ;傳回尾數(shù)的低字節(jié)
MOV @R0,A
DEC R0
MOV A,R3 ;傳回尾數(shù)的高字節(jié)
MOV @R0,A
DEC R0
MOV A,R2 ;取結(jié)果的階碼
MOV C,1FH ;取結(jié)果的數(shù)符
MOV ACC.7,C ;拼入階碼中
MOV @R0,A
CLR ACC.7 ;不考慮數(shù)符
CLR OV ;清除溢出標(biāo)志
CJNE A,#3FH,MV01;階碼是否上溢？ ******** 應(yīng)為#40H
SETB OV ;設(shè)立溢出標(biāo)志
MV01: MOV A,@R0 ;取出帶數(shù)符的階碼
RET
MVR0: MOV A,@R0 ;將[R0]傳送到第一工作區(qū)中的子程序
MOV C,ACC.7 ;將數(shù)符保存在位1FH中
MOV 1FH,C
MOV C,ACC.6 ;將階碼擴充為８ｂｉｔ補碼
MOV ACC.7,C
MOV R2,A ;存放在R2中
INC R0
MOV A,@R0 ;將尾數(shù)高字節(jié)存放在R3中
MOV R3,A ;
INC R0
MOV A,@R0 ;將尾數(shù)低字節(jié)存放在R4中
MOV R4,A
DEC R0 ;恢復(fù)數(shù)據(jù)指針
DEC R0
RET
MVR1: MOV A,@R1 ;將[R1]傳送到第二工作區(qū)中的子程序
MOV C,ACC.7 ;將數(shù)符保存在位1EH中
MOV 1EH,C
MOV C,ACC.6 ;將階碼擴充為８ｂｉｔ補碼
MOV ACC.7,C
MOV R5,A ;存放在R5中
INC R1
MOV A,@R1 ;將尾數(shù)高字節(jié)存放在R6中
MOV R6,A
INC R1
MOV A,@R1 ;將尾數(shù)低字節(jié)存放在R7中
MOV R7,A
DEC R1 ;恢復(fù)數(shù)據(jù)指針
DEC R1
RET
AS1: MOV A,R6 ;讀取第二操作數(shù)尾數(shù)高字節(jié)
ORL A,R7
JZ AS2 ;第二操作數(shù)為零，不必運算
MOV A,R3 ;讀取第一操作數(shù)尾數(shù)高字節(jié)
ORL A,R4
JNZ EQ
MOV A,R6 ;第一操作數(shù)為零，結(jié)果以第二操作數(shù)為準(zhǔn)
MOV R3,A
MOV A,R7
MOV R4,A
MOV A,R5
MOV R2,A
MOV C,1EH
MOV 1FH,C
AS2: RET
EQ: MOV A,R2 ;對階，比較兩個操作數(shù)的階碼
XRL A,R5
JZ AS4 ;階碼相同，對階結(jié)束
JB ACC.7,EQ3;階符互異
MOV A,R2 ;階符相同，比較大小
CLR C
SUBB A,R5
JC EQ4
EQ2: CLR C ;第二操作數(shù)右規(guī)一次
MOV A,R6 ;尾數(shù)縮小一半
RRC A
MOV R6,A
MOV A,R7
RRC A
MOV R7,A
INC R5 ;階碼加一
ORL A,R6 ;尾數(shù)為零否？
JNZ EQ ;尾數(shù)不為零，繼續(xù)對階
MOV A,R2 ;尾數(shù)為零，提前結(jié)束對階
MOV R5,A
SJMP AS4
EQ3: MOV A,R2 ;判斷第一操作數(shù)階符
JNB ACC.7,EQ2;如為正，右規(guī)第二操作數(shù)
EQ4: CLR C
LCALL RR1 ;第一操作數(shù)右規(guī)一次
ORL A,R3 ;尾數(shù)為零否？
JNZ EQ ;不為零，繼續(xù)對階
MOV A,R5 ;尾數(shù)為零，提前結(jié)束對階
MOV R2,A
AS4: JB F0,AS5 ;尾數(shù)加減判斷
MOV A,R4 ;尾數(shù)相加
ADD A,R7
MOV R4,A
MOV A,R3
ADDC A,R6
MOV R3,A
JNC AS2
LJMP RR1 ;有進位，右規(guī)一次
AS5: CLR C ;比較絕對值大小
MOV A,R4
SUBB A,R7
MOV B,A
MOV A,R3
SUBB A,R6
JC AS6
MOV R4,B ;第一尾數(shù)減第二尾數(shù)
MOV R3,A
LJMP RLN ;結(jié)果規(guī)格化
AS6: CPL 1FH ;結(jié)果的符號與第一操作數(shù)相反
CLR C ;結(jié)果的絕對值為第二尾數(shù)減第一尾數(shù)
MOV A,R7
SUBB A,R4
MOV R4,A
MOV A,R6
SUBB A,R3
MOV R3,A
RLN: MOV A,R3 ;浮點數(shù)規(guī)格化
ORL A,R4 ;尾數(shù)為零否？
JNZ RLN1
MOV R2,#0C1H;階碼取最小值 ******？？應(yīng)為#C0H
RET
RLN1: MOV A,R3
JB ACC.7,RLN2;尾數(shù)最高位為一否？
CLR C ;不為一，左規(guī)一次
LCALL RL1
SJMP RLN ;繼續(xù)判斷
RLN2: CLR OV ;規(guī)格化結(jié)束
RET
RL1: MOV A,R4 ;第一操作數(shù)左規(guī)一次
RLC A ;尾數(shù)擴大一倍
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
DEC R2 ;階碼減一
CJNE R2,#0C0H,RL1E;階碼下溢否？ ***** 應(yīng)改為CJNE R2，#0BFH，RL1E；
CLR A
MOV R3,A ;階碼下溢，操作數(shù)以零計
MOV R4,A
MOV R2,#0C1H ; ******應(yīng)改為MOV R2，#0C0H
RL1E: CLR OV
RET
RR1: MOV A,R3 ;第一操作數(shù)右規(guī)一次
RRC A ;尾數(shù)縮小一半
MOV R3,A
MOV A,R4
RRC A
MOV R4,A
INC R2 ;階碼加一
CLR OV ;清溢出標(biāo)志
CJNE R2,#40H,RR1E;階碼上溢否？
MOV R2,#3FH ;階碼溢出
SETB OV
RR1E: RET
; （４） 標(biāo)號： ＦＭＵＬ 功能：浮點數(shù)乘法
;入口條件：被乘數(shù)在[R0]中，乘數(shù)在[R1]中。
;出口信息：OV=0時，積仍在[R0]中，OV=1時，溢出。
;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：６字節(jié)
FMUL: LCALL MVR0 ;將[R0]傳送到第一工作區(qū)中
MOV A,@R0
XRL A,@R1 ;比較兩個操作數(shù)的符號
RLC A
MOV 1FH,C ;保存積的符號
LCALL MUL0 ;計算積的絕對值
LJMP MOV0 ;將結(jié)果傳回到[R0]中
MUL0: LCALL MVR1 ;將[R1]傳送到第二工作區(qū)中
MUL1: MOV A,R3 ;第一尾數(shù)為零否？
ORL A,R4
JZ MUL6
MOV A,R6 ;第二尾數(shù)為零否？
ORL A,R7
JZ MUL5
MOV A,R7 ;計算R3R4×R6R7－→R3R4
MOV B,R4
MUL AB
MOV A,B
XCH A,R7
MOV B,R3
MUL AB
ADD A,R7
MOV R7,A
CLR A
ADDC A,B
XCH A,R4
MOV B,R6
MUL AB
ADD A,R7
MOV R7,A
MOV A,B
ADDC A,R4
MOV R4,A
CLR A
RLC A
XCH A,R3
MOV B,R6
MUL AB
ADD A,R4
MOV R4,A
MOV A,B
ADDC A,R3
MOV R3,A
JB ACC.7,MUL2;積為規(guī)格化數(shù)否？ R7四舍五入
MOV A,R7 ;左規(guī)一次
RLC A
MOV R7,A
LCALL RL1
MUL2: MOV A,R7
JNB ACC.7,MUL3
INC R4
MOV A,R4
JNZ MUL3
INC R3
MOV A,R3
JNZ MUL3
MOV R3,#80H
INC R2
MUL3: MOV A,R2 ;求積的階碼
ADD A,R5
MD: MOV R2,A ;階碼溢出判斷
JB ACC.7,MUL4
JNB ACC.6,MUL6
MOV R2,#3FH ;階碼上溢，設(shè)立標(biāo)志
SETB OV
RET
MUL4: JB ACC.6,MUL6
MUL5: CLR A ;結(jié)果清零（因子為零或階碼下溢）
MOV R3,A
MOV R4,A
MOV R2,#41H
MUL6: CLR OV
RET
; （５） 標(biāo)號： ＦＤＩＶ 功能：浮點數(shù)除法
;入口條件：被除數(shù)在[R0]中，除數(shù)在[R1]中。
;出口信息：OV=0時，商仍在[R0]中，OV=1時，溢出。
;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： ５字節(jié)
FDIV: INC R0
MOV A,@R0
INC R0
ORL A,@R0
DEC R0
DEC R0
JNZ DIV1
MOV @R0,#41H;被除數(shù)為零，不必運算
CLR OV
RET
DIV1: INC R1
MOV A,@R1
INC R1
ORL A,@R1
DEC R1
DEC R1
JNZ DIV2
SETB OV ;除數(shù)為零，溢出
RET
DIV2: LCALL MVR0 ;將[R0]傳送到第一工作區(qū)中
MOV A,@R0
XRL A,@R1 ;比較兩個操作數(shù)的符號
RLC A
MOV 1FH,C ;保存結(jié)果的符號
LCALL MVR1 ;將[R1]傳送到第二工作區(qū)中
LCALL DIV3 ;調(diào)用工作區(qū)浮點除法
LJMP MOV0 ;回傳結(jié)果
DIV3: CLR C ;比較尾數(shù)的大小
MOV A,R4
SUBB A,R7
MOV A,R3
SUBB A,R6
JC DIV4
LCALL RR1 ;被除數(shù)右規(guī)一次
SJMP DIV3
DIV4: CLR A ;借用R0R1R2作工作寄存器
XCH A,R0 ;清零并保護之
PUSH ACC
CLR A
XCH A,R1
PUSH ACC
MOV A,R2
PUSH ACC
MOV B,#10H ;除法運算，R3R4／R6R7－→R0R1
DIV5: CLR C
MOV A,R1
RLC A
MOV R1,A
MOV A,R0
RLC A
MOV R0,A
MOV A,R4
RLC A
MOV R4,A
XCH A,R3
RLC A
XCH A,R3
MOV F0,C
CLR C
SUBB A,R7
MOV R2,A
MOV A,R3
SUBB A,R6
ANL C,/F0
JC DIV6
MOV R3,A
MOV A,R2
MOV R4,A
INC R1
DIV6: DJNZ B,DIV5
MOV A,R6 ;四舍五入
CLR C
RRC A
SUBB A,R3
CLR A
ADDC A,R1 ;將結(jié)果存回R3R4
MOV R4,A
CLR A
ADDC A,R0
MOV R3,A
POP ACC ;恢復(fù)R0R1R2
MOV R2,A
POP ACC
MOV R1,A
POP ACC
MOV R0,A
MOV A,R2 ;計算商的階碼
CLR C
SUBB A,R5
LCALL MD ;階碼檢驗
LJMP RLN ;規(guī)格化
; （６） 標(biāo)號： ＦＣＬＲ 功能：浮點數(shù)清零
;入口條件：操作數(shù)在[R0]中。
;出口信息：操作數(shù)被清零。
;影響資源：A 堆棧需求： ２字節(jié)
FCLR: INC R0
INC R0
CLR A
MOV @R0,A
DEC R0
MOV @R0,A
DEC R0
MOV @R0,#41H
RET
; （７） 標(biāo)號： ＦＺＥＲ 功能：浮點數(shù)判零
;入口條件：操作數(shù)在[R0]中。
;出口信息：若累加器A為零，則操作數(shù)[R0]為零，否則不為零。
;影響資源：A 堆棧需求： ２字節(jié)
FZER: INC R0
INC R0
MOV A,@R0
DEC R0
ORL A,@R0
DEC R0
JNZ ZERO
MOV @R0,#41H
ZER RET
; （８） 標(biāo)號： ＦＭＯＶ 功能：浮點數(shù)傳送
;入口條件：源操作數(shù)在[R1]中，目標(biāo)地址為[R0]。
;出口信息：[R0]=[R1]，[R1]不變。
;影響資源：A 堆棧需求： ２字節(jié)
FMOV: INC R0
INC R0
INC R1
INC R1
MOV A,@R1
MOV @R0,A
DEC R0
DEC R1
MOV A,@R1
MOV @R0,A
DEC R0
DEC R1
MOV A,@R1
MOV @R0,A
RET
; （８.1） 標(biāo)號： ＦＭＯＶR0 功能：浮點數(shù)傳送
;入口條件：源操作數(shù)在[R0]中，目標(biāo)地址為[R1]。
;出口信息：[R1]=[R0]，[R0]不變。
;影響資源：A 堆棧需求： ２字節(jié)
FMOVR0: INC R1
INC R1
INC R0
INC R0
MOV A,@R0
MOV @R1,A
DEC R1
DEC R0
MOV A,@R0
MOV @R1,A
DEC R1
DEC R0
MOV A,@R0
MOV @R1,A
RET
; （２４）標(biāo)號： ＤＴＯＦ 功能：雙字節(jié)十六進制定點數(shù)轉(zhuǎn)換成格式化浮點數(shù)
;入口條件：雙字節(jié)定點數(shù)的絕對值在[R0]中，數(shù)符在位1FH中，整數(shù)部分的位數(shù)在A中。
;出口信息：轉(zhuǎn)換成格式化浮點數(shù)在[R0]中（三字節(jié)）。
;影響資源：PSW、A、R2、R3、R4、位1FH 堆棧需求： ６字節(jié)
DTOF: MOV R2,A ;按整數(shù)的位數(shù)初始化階碼
MOV A,@R0 ;將定點數(shù)作尾數(shù)
MOV R3,A
INC R0
MOV A,@R0
MOV R4,A
DEC R0
LCALL RLN ;進行規(guī)格化
LJMP MOV0 ;傳送結(jié)果到[R0]中
; （２５） 標(biāo)號： ＦＴＯＤ 功能：格式化浮點數(shù)轉(zhuǎn)換成雙字節(jié)定點數(shù)
;入口條件：格式化浮點操作數(shù)在[R0]中。
;出口信息：OV=1時溢出，OV=0時轉(zhuǎn)換成功：定點數(shù)的絕對值在[R0]中（雙字節(jié)），數(shù)符
;在位1FH中，F(xiàn)0=1 時為整數(shù)，CY=1時為一字節(jié)整數(shù)一字節(jié)小數(shù)，否則為純小數(shù)。
;影響資源：PSW、A、B、R2、R3、R4、位1FH 堆棧需求： ６字節(jié)
FTOD: LCALL MVR0 ;將[R0]傳送到第一工作區(qū)
MOV A,R2
JZ FTD4 ;階碼為零，純小數(shù)
JB ACC.7,FTD4;階碼為負，純小數(shù)
SETB C
SUBB A,#10H
JC FTD1
SETB OV ;階碼大于１６，溢出
RET
FTD1: SETB C
MOV A,R2
SUBB A,#8 ;階碼大于８否？
JC FTD3
FTD2: MOV B,#10H ;階碼大于８，按雙字節(jié)整數(shù)轉(zhuǎn)換
LCALL FTD8
SETB F0 ;設(shè)立雙字節(jié)整數(shù)標(biāo)志
CLR C
CLR OV
RET
FTD3: MOV B,#8 ;按一字節(jié)整數(shù)一字節(jié)小數(shù)轉(zhuǎn)換
LCALL FTD8
SETB C ; 設(shè)立一字節(jié)整數(shù)一字節(jié)小數(shù)標(biāo)志
CLR F0
CLR OV
RET
FTD4: MOV B,#0 ;按純小數(shù)轉(zhuǎn)換
LCALL FTD8
CLR OV ;設(shè)立純小數(shù)標(biāo)志
CLR F0
CLR C
RET
FTD8: MOV A,R2 ;按規(guī)定的整數(shù)位數(shù)進行右規(guī)***階碼是擴展后的值
CJNE A,B,FTD9
MOV A,R3 ;將雙字節(jié)結(jié)果傳送到[R0]中
MOV @R0,A
INC R0
MOV A,R4
MOV @R0,A
DEC R0
RET
FTD9: CLR C
LCALL RR1 ;右規(guī)一次
SJMP FTD8
; （２６） 標(biāo)號： ＢＴＯＦ 功能：浮點ＢＣＤ碼轉(zhuǎn)換成格式化浮點數(shù)
;入口條件：浮點ＢＣＤ碼操作數(shù)在[R0]中。
;出口信息：轉(zhuǎn)換成的格式化浮點數(shù)仍在[R0]中。
;影響資源：PSW、A、B、R2～R7、位1DH～1FH 堆棧需求：６字節(jié)
BTOF: INC R0 ;判斷是否為零。
INC R0
MOV A,@R0
MOV R7,A
DEC R0
MOV A,@R0
MOV R6,A
DEC R0
ORL A,R7
JNZ BTF0
MOV @R0,#41H;為零，轉(zhuǎn)換結(jié)束。
RET
BTF0: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C ;保存數(shù)符。
CLR 1FH ;以絕對值進行轉(zhuǎn)換。
MOV C,ACC.6 ;擴充階碼為八位。
MOV ACC.7,C
MOV @R0,A
JNC BTF1
ADD A,#19 ;是否小于１Ｅ－１９？
JC BTF2
MOV @R0,#41H ;小于１Ｅ－１９時以０計。
INC R0
MOV @R0,#0
INC R0
MOV @R0,#0
DEC R0
DEC R0
RET
BTF1: SUBB A,#19
JC BTF2
MOV A,#3FH ;大于１Ｅ１９時封頂。
MOV C,1DH
MOV ACC.7,C
MOV @R0,A
INC R0
MOV @R0,#0FFH
INC R0
MOV @R0,#0FFH
DEC R0
DEC R0
RET
BTF2: CLR A ;準(zhǔn)備將ＢＣＤ碼尾數(shù)轉(zhuǎn)換成十六進制浮點數(shù)。
MOV R4,A
MOV R3,A
MOV R2,#10H ;至少兩個字節(jié)。
BTF3: MOV A,R7
ADD A,R7
DA A
MOV R7,A
MOV A,R6
ADDC A,R6
DA A
MOV R6,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
DEC R2
JNB ACC.7,BTF3;直到尾數(shù)規(guī)格化。
MOV A,R6 ;四舍五入。
ADD A,#0B0H ; ******加#80H，也可以
CLR A
ADDC A,R4
MOV R4,A
CLR A
ADDC A,R3
MOV R3,A
JNC BTF4
MOV R3,#80H ; ****有進位右規(guī)一次
INC R2
BTF4: MOV DPTR,#BTFL;準(zhǔn)備查表得到十進制階碼對應(yīng)的浮點數(shù)。
MOV A,@R0
ADD A,#19 ;計算表格偏移量。
MOV B,#3
MUL AB
ADD A,DPL
MOV DPL,A
JNC BTF5
INC DPH
BTF5: CLR A ;查表。
MOVC A,@A+DPTR
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
MOV A,#1
MOVC A,@A+DPTR
MOV R6,A
MOV A,#2
MOVC A,@A+DPTR
MOV R7,A
LCALL MUL1 ;將階碼對應(yīng)的浮點數(shù)和尾數(shù)對應(yīng)的浮點數(shù)相乘。
MOV C,1DH ;取出數(shù)符。
MOV 1FH,C
LJMP MOV0 ;傳送轉(zhuǎn)換結(jié)果。
; （２７） 標(biāo)號： ＦＴＯＢ 功能：格式化浮點數(shù)轉(zhuǎn)換成浮點ＢＣＤ碼
;入口條件：格式化浮點操作數(shù)在[R0]中。
;出口信息：轉(zhuǎn)換成的浮點ＢＣＤ碼仍在[R0]中。
;影響資源：PSW、A、B、R2～R7、位1DH～1FH 堆棧需求：６字節(jié)
FTOB: INC R0
MOV A,@R0
INC R0
ORL A,@R0
DEC R0
DEC R0
JNZ FTB0
MOV @R0,#41H
RET
FTB0: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C
CLR ACC.7
MOV @R0,A
LCALL MVR0
MOV DPTR,#BFL0;絕對值大于或等于１時的查表起點。
MOV B,#0 ;十的０次冪。
MOV A,R2
JNB ACC.7,FTB1
MOV DPTR,#BTFL;絕對值小于１Ｅ－６時的查表起點。
MOV B,#0EDH ;十的－１９次冪。
ADD A,#16
JNC FTB1
MOV DPTR,#BFLN;絕對值大于或等于１Ｅ－６時的查表起點。
MOV B,#0FAH ;十的－６次冪。
FTB1: CLR A ;查表，找到一個比待轉(zhuǎn)換浮點數(shù)大的整數(shù)冪。
MOVC A,@A+DPTR
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
MOV A,#1
MOVC A,@A+DPTR
MOV R6,A
MOV A,#2
MOVC A,@A+DPTR
MOV R7,A
MOV A,R5 ;和待轉(zhuǎn)換浮點數(shù)比較。
CLR C
SUBB A,R2
JB ACC.7,FTB2;差為負數(shù)。
JNZ FTB3
MOV A,R6
CLR C
SUBB A,R3
JC FTB2
JNZ FTB3
MOV A,R7
CLR C
SUBB A,R4
JC FTB2
JNZ FTB3
MOV R5,B ;正好是表格中的數(shù)。
INC R5 ;冪加一。
MOV R6,#10H ;尾數(shù)為０·１０００。
MOV R7,#0
SJMP FTB6 ;傳送轉(zhuǎn)換結(jié)果。
FTB2: INC DPTR ;準(zhǔn)備表格下一項。
INC DPTR
INC DPTR
INC B ;冪加一。
SJMP FTB1 ;
FTB3: PUSH B ;保存冪值。
LCALL DIV3 ;相除，得到一個二進制浮點數(shù)的純小數(shù)。
FTB4: MOV A,R2 ;取階碼。
JZ FTB5 ;為零嗎？
CLR C ;
LCALL RR1 ;右規(guī)。
SJMP FTB4
FTB5: POP ACC ;取出冪值。
MOV R5,A ;作為十進制浮點數(shù)的階碼。
LCALL HB2 ;轉(zhuǎn)換尾數(shù)的十分位和百分位。
MOV R6,A
LCALL HB2 ;轉(zhuǎn)換尾數(shù)的千分位和萬分位。
MOV R7,A
MOV A,R3 ;四舍五入。
RLC A
CLR A
ADDC A,R7
DA A
MOV R7,A
CLR A
ADDC A,R6
DA A
MOV R6,A
JNC FTB6
MOV R6,#10H
INC R5
FTB6: INC R0 ;存放轉(zhuǎn)換結(jié)果。
INC R0
MOV A,R7
MOV @R0,A
DEC R0
MOV A,R6
MOV @R0,A
DEC R0
MOV A,R5
MOV C,1DH ;取出數(shù)符。
MOV ACC.7,C
MOV @R0,A
RET
HB2: MOV A,R4 ; 尾數(shù)擴大１００倍。
MOV B,#100
MUL AB
MOV R4,A
MOV A,B
XCH A,R3
MOV B,#100
MUL AB
ADD A,R3
MOV R3,A
JNC HB21
INC B
HB21: MOV A,B ;將整數(shù)部分轉(zhuǎn)換成ＢＣＤ碼。
MOV B,#10
DIV AB
SWAP A
ORL A,B
RET
BTFL: DB 41H,0ECH,1EH ;1.0000E-19
DB 45H,93H,93H ;1.0000E-18
DB 48H,0B8H,78H ;1.0000E-17
DB 4BH,0E6H,96H ;1.0000E-16
DB 4FH,90H,1DH ;1.0000E-15
DB 52H,0B4H,25H ;1.0000E-14
DB 55H,0E1H,2EH ;1.0000E-13
DB 59H,8CH,0BDH ;1.0000E-12
DB 5CH,0AFH,0ECH ;1.0000E-11
DB 5FH,0DBH,0E7H ;1.0000E-10
DB 63H,89H,70H ;1.0000E-9
DB 66H,0ABH,0CCH ;1.0000E-8
DB 69H,0D6H,0C0H ;1.0000E-7
BFLN: DB 6DH,86H,38H ;1.0000E-6
DB 70H,0A7H,0C6H ;1.0000E-5
DB 73H,0D1H,0B7H ;1.0000E-4
DB 77H,83H,12H ;1.0000E-3
DB 7AH,0A3H,0D7H ;1.0000E-2
DB 7DH,0CCH,0CDH ;1.0000E-1
BFL0: DB 1,80H,00H ;1.0000
DB 4,0A0H,00H ;；1.0000E1
DB 7,0C8H,00H ;1.0000E2
DB 0AH,0FAH,00H ;1.0000E3
DB 0EH,9CH,40H ;1.0000E4
DB 11H,0C3H,50H ;1.0000E5
DB 14H,0F4H,24H ;1.0000E6
DB 18H,98H,97H ;1.0000E7
DB 1BH,0BEH,0BCH ;1.0000E8
DB 1EH,0EEH,6BH ;1.0000E9
DB 22H,95H,03H ;1.0000E10
DB 25H,0BAH,44H ;1.0000E11
DB 28H,0E8H,0D5H ;1.0000E12
DB 2CH,91H,85H ; 1.0000E13
DB 2FH,0B5H,0E6H ;1.0000E14
DB 32H,0E3H,60H ;1.0000E15
DB 36H,8EH,1CH ;1.0000E16
DB 39H,31H,0A3H ;1.0000E17
DB 3CH,0DEH,0BH ;1.0000E18
DB 40H,8AH,0C7H ;1.0000E19 |
|
66821730(技術(shù)支持)
