;摘要：本系統(tǒng)由單片機(jī)系統(tǒng)、矩陣鍵盤、LED顯示和報(bào)警系統(tǒng)組成。系統(tǒng)能完成開鎖、超時(shí) ;報(bào)警、超次鎖定、管理員解密、修改用戶密碼基本的密碼鎖的功能。除上述基本的密碼鎖功 ;能外，還具有調(diào)電存儲(chǔ)、聲光提示等功能，依據(jù)實(shí)際的情況還可以添加遙控功能。本系統(tǒng)成 ;本低廉，功能實(shí)用
;********************************************
;********* 電子密碼鎖 *********
;********************************************
;********* 2005/12/24 *********
;********************************************
;顯示緩沖區(qū)
;LED1 EQU 6FH
BUFF EQU 6EH
TIMERS1 EQU 6DH ;輸入回車的次數(shù)
TIMERS2 EQU 6CH ;報(bào)警的次數(shù)
TIMERS EQU 6BH ;輸入數(shù)字的位數(shù)
;LED6 EQU 6AH
;密碼緩沖區(qū)
PS1 EQU 69H
PS2 EQU 68H
PS3 EQU 67H
PS4 EQU 66H
PS5 EQU 65H
PS6 EQU 64H
;AT24C02讀取緩沖區(qū)
AT1 EQU 63H
AT2 EQU 62H
AT3 EQU 61H
AT4 EQU 60H
AT5 EQU 5FH
AT6 EQU 5EH
;按鍵標(biāo)志位
F_1 BIT 20H
F_2 BIT 21H
F_3 BIT 22H
F_4 BIT 23H
BUF_FULL BIT 24H ;密碼已經(jīng)夠六位的標(biāo)志位，為1表示滿
CH_STATE BIT 25H ;系統(tǒng)更改的狀態(tài)標(biāo)志位，為1表示busy
FLAG1 BIT 26H ;功能鍵標(biāo)志位，為1表示功能按鍵。
F_F1 BIT 27H
F_F2 BIT 28H
PSW_F BIT 29H ;密碼是否正確的標(biāo)志位
;口資源定義
SPK BIT P2.1
JDQ BIT P2.3
SDA BIT P2.4 ;定義串口數(shù)據(jù)端
SCL BIT P2.5
;發(fā)光二極管燈
L1 BIT P1.0
L2 BIT P1.1
L3 BIT P1.2
;
ORG 0000H
AJMP MAIN
ORG 000BH
;AJMP TIMER0
ORG 001BH
;AJMP TIMER1
ORG 0030H
MAIN:MOV SP, #70H
MOV TMOD, #11H
MOV TH0, #3CH
MOV TL0, #0B0H
MOV TH1, #3CH
MOV TL1, #0B0H
CLR F_1 ;清除標(biāo)志位
CLR F_2
CLR F_3
CLR F_4
CLR BUF_FULL
CLR CH_STATE
CLR FLAG1
CLR F_F1
CLR F_F2
CLR PSW_F
MOV BUFF,#00H ;調(diào)用
LCALL INITPS ;初始化環(huán)境
LCALL INITAT
LCALL XSA ;調(diào)用默認(rèn)顯示
MOV TIMERS1,#00H
NOP
MOV PS1, #11H ;初始化密碼830620
MOV PS2, #0AH
MOV PS3, #02H
MOV PS4, #13H
MOV PS5, #0BH
MOV PS6, #02H
START:NOP ;程序開始
LCALL CH_KEY ;檢查鍵盤
AJMP START ;返回
CH_KEY:LCALL KS ;檢查有沒有按鍵按下
JNZ LK1
AJMP CH_KEY
LK1:
LCALL T12MS
ACALL KS
JNZ LK2
RET
LK2:
NOP
LCALL SBIE ;按鍵識(shí)別子程序
MOV BUFF, A ;送緩沖區(qū)以識(shí)別是數(shù)字鍵還是功能鍵？
LCALL CH_KF ;判斷按鍵功能。
JB FLAG1 ,KEY_FUN ;標(biāo)志為1，則為功能鍵
;***********數(shù)字按鍵輸入并且存放到緩沖區(qū)內(nèi)等待比較***********
KEY_DIG:NOP ;設(shè)一標(biāo)志，辨別輸入是否滿
;SETB TR0
INC TIMERS ;輸入數(shù)字的位數(shù)
MOV A, TIMERS
CLR C
SUBB A, #01H
JNZ PS_2
MOV PS1, BUFF ;依照順序存放密碼
AJMP NEXT
PS_2:MOV A, TIMERS
SUBB A, #02H
CLR C
JNZ PS_3
MOV PS2, BUFF
AJMP NEXT
PS_3:MOV A, TIMERS
CLR C
SUBB A, #03H
JNZ PS_4
MOV PS3, BUFF
AJMP NEXT
PS_4:MOV A, TIMERS
CLR C
SUBB A, #04
JNZ PS_5
MOV PS4, BUFF
AJMP NEXT
PS_5:MOV A, TIMERS
CLR C
SUBB A, #05
JNZ PS_6
MOV PS5, BUFF
AJMP NEXT
PS_6:MOV A, TIMERS
CLR C
SUBB A, #06H
JNZ CH_KEY
MOV PS6, BUFF
NEXT:LCALL XSC
MOV R7, TIMERS ;比較輸入的次數(shù)。
CJNE R7, #06H ,FULL
FULL:JC NEXT9
SETB BUF_FULL
MOV TIMERS,#06H
CLR L3
NOP
CLR P2.1
LCALL T100MSD
SETB P2.1
NOP
AJMP CH_KEY
NEXT9:CLR P2.1 ;密碼輸入一位，鳴叫一聲。
CLR L3
LCALL T100MSD ;延時(shí)100ms
SETB L3
SETB P2.1
AJMP CH_KEY
;*****************功能按鍵比較并且跳轉(zhuǎn)*************
KEY_FUN:
CLR FLAG1
CLR C
MOV A, BUFF
SUBB A, #03H ;按鍵CL跳轉(zhuǎn)
JNZ EN_C
AJMP CL
EN_C:CLR C
MOV A, BUFF ;按鍵EN跳轉(zhuǎn)
SUBB A, #00H
JNZ F1_C
AJMP EN
F1_C:CLR C
MOV A, BUFF
SUBB A, #1BH
JNZ F2_C
AJMP FU1
F2_C:CLR C
MOV A, BUFF
SUBB A, #1AH
JNZ F3_C
AJMP FU2
F3_C:CLR C
MOV A, BUFF
SUBB A, #19H
JNZ F4_C
AJMP FU3
F4_C:CLR C
MOV A, BUFF
SUBB A, #18H
JZ FU4
EXIT8:NOP
LJMP CH_KEY
;***************開門子程序 ********************************
CL:NOP
SETB L3
MOV BUFF, #00H ;消密碼緩沖
MOV TIMERS,#00H
LCALL INITPS ;消除AT緩沖，加調(diào)電存儲(chǔ)后一定要加上
LCALL XSC
LCALL BP
LCALL BP
LCALL T100MSD
LCALL BP
CLR FLAG1
AJMP CH_KEY
FU4:NOP
LCALL BP
LCALL T100MSD
LCALL BP
LCALL T100MSD
LCALL BP
LCALL T100MSD
LCALL BP
LCALL T100MSD
LCALL BP
CLR FLAG1
AJMP CH_KEY
FU3:NOP
LCALL BP
LCALL T100MSD
LCALL BP
LCALL KILLXS ;關(guān)閉顯示
CLR FLAG1
AJMP CH_KEY
FU1:NOP
LCALL XSC
JB F_F1, NEXT_F1
CLR L1
LCALL BP
SETB F_F1
AJMP CH_KEY
NEXT_F1:SETB L1
LCALL BP
CLR F_F1
;LCALL CH_STATE ;查看現(xiàn)在的狀態(tài)以防誤按
;SETB TR1 ;報(bào)警限制暫時(shí)不開
;INC F_F1
CLR FLAG1
AJMP CH_KEY
FU2:NOP
JB F_F2, NEXT_F2
CLR L2
LCALL BP
SETB F_F2
AJMP CH_KEY
NEXT_F2:SETB L2
LCALL BP
CLR F_F2
CLR FLAG1
AJMP CH_KEY
;***************按鍵的功能描述*************************
EN:NOP
JB BUF_FULL, GOON
AJMP EXIT
GOON:CLR BUF_FULL
JB F_F2, AT_WRON ;F2按鍵標(biāo)志,若為1，則調(diào)用修改密碼子程序。
LCALL AT_RADE
LCALL C_PSW ;比較密碼子程序
JB PSW_F,OPEN ;密碼比較正確，則調(diào)用開鎖子程序
LCALL XSD
INC TIMERS2
MOV R7,TIMERS2 ;密碼錯(cuò)誤，調(diào)入輸入密碼輸入次數(shù)，準(zhǔn)備鎖定鍵盤
CJNE R7,#03H,D0
D0:JC NEXT1 ;錯(cuò)誤次數(shù)小3次
LCALL XSE ;鎖定5分鐘
LCALL WARN2S
LCALL LOCK_1M
NEXT1:LCALL WARN2S ;報(bào)警2分鐘
LCALL XSA
EXIT:LCALL INITPS
MOV BUFF, #00H
CLR FLAG1
MOV TIMERS, #00H
AJMP CH_KEY ;跳出
AT_WRON:LCALL AT_WR
LCALL XSF
LCALL BP
LCALL T100MSD
LCALL BP
LCALL T500MSD
LCALL KILLXS
LCALL T500MSD
LCALL XSF
LCALL T500MSD
LCALL KILLXS
LCALL T500MSD
LCALL XSF
LCALL T500MSD
NOP
NOP
LCALL XSA
AJMP EXIT
OPEN:MOV A, TIMERS1
CJNE A, #09H,CLT1
CLT1:JC GOON1
MOV TIMERS1,#00H
GOON1:INC TIMERS1 ;輸入回車的次數(shù)
MOV TIMERS2,#00H
SETB L3
CLR PSW_F
LCALL XSB
CLR JDQ ;開門
LCALL BP
LCALL BP
LCALL BP
LCALL BP
LCALL SEC
LCALL SEC
LCALL SEC
LCALL SEC
LCALL SEC
LCALL SEC
LCALL SEC
LCALL SEC
SETB JDQ
LCALL XSA
NOP
AJMP EXIT
;**************各類子程序********************************
;**** 注意清楚緩沖區(qū)時(shí)AT1...AT6不應(yīng)在初始化中執(zhí)行,以 ***
;**** 防兩緩沖區(qū)都為0,相同開鎖 ***
;********************************************************
CLR_BUF:MOV R7, #06H
MOV R0, #6FH
LOOP1:MOV A, #00H
MOV @R0, A
DEC R0
DJNZ R7,LOOP1
RET
;*************初始化顯示緩沖區(qū)以及其他緩沖區(qū)**************
INITPS:PUSH ACC
PUSH PSW
MOV R7, #06H
MOV R1, #PS1
MOV A, #00H
INIT_PS:MOV @R1, A
DEC R1
DJNZ R7, INIT_PS
POP PSW
POP ACC
NOP
RET
INITAT:PUSH ACC
PUSH PSW
MOV R7,#06H
MOV R1,#AT1
MOV A, #00H
INIT_AT:MOV @R1, A
DEC R1
DJNZ R7, INIT_AT
MOV TIMERS,#00H ;密碼輸入的次數(shù)清零。
POP PSW
POP ACC
RET
;************* 按鍵識(shí)別子程序 ***************************
SBIE:MOV R2, #0EFH ;識(shí)別按鍵子程序,數(shù)據(jù)送A保存，課本P146頁。
MOV R4, #00H
LK4:MOV A, R2
MOV P0, A
NOP
MOV A, P0
JB ACC.0,LONE
MOV A, #00H
AJMP LKP
LONE:JB ACC.1,LTWO
MOV A, #08H
AJMP LKP
LTWO:JB ACC.2,LTHR
MOV A, #10H
AJMP LKP
LTHR:JB ACC.3,NEXTT ;判斷下一列
MOV A, #18H
LKP:ADD A, R4
PUSH ACC
LK3:ACALL KS
JNZ LK3
POP ACC
RET
NEXTT:INC R4
MOV A, R2
JNB ACC.7,KND
RL A
MOV R2, A
AJMP LK4
KND:AJMP CH_KEY
KS:MOV P0, #0FH
NOP
MOV A, P0
CPL A
ANL A, #0FH
NOP
RET
CH_KF:CLR C
MOV A, BUFF ;判斷是數(shù)字按鍵還是功能按鍵,為1表示功能鍵
CJNE A, #17H, KY
KY:JC SET_CH ;假若是數(shù)字按鍵則標(biāo)志置為0
SETB FLAG1 ;假若是功能按鍵則標(biāo)志置為1
AJMP CHKE_END
SET_CH:CLR C
MOV A, BUFF
SUBB A, #00H
JNZ EN_CH
SETB FLAG1
AJMP CH_END
EN_CH:MOV A, BUFF
SUBB A, #03H
JNZ DIG
SETB FLAG1
AJMP CH_END
DIG:CLR FLAG1
CH_END:NOP
CHKE_END:RET
T12MS:MOV R7, #18H
TM1:MOV R6, #0FFH
TM66:DJNZ R6, TM66
DJNZ R7, TM1
RET
;****************檢驗(yàn)密碼正誤******************************
C_PSW:PUSH PSW
PUSH ACC
MOV R2,#06H
MOV R0,#PS1
MOV R1,#AT1
C_P:CLR C
MOV A,@R0
SUBB A,@R1
JNZ RETURN
DEC R0
DEC R1
DJNZ R2,C_P
NOP
SETB PSW_F
AJMP EXIT7
RETURN:CLR PSW_F
EXIT7:NOP
POP ACC
POP PSW
RET
;×××××××××××××××××鎖定，鳴笛子程序××××××××××××
LOCK_1M:MOV R4,#3CH ;鎖定1分鐘
M1_LOOP:LCALL SEC
DJNZ R4,M1_LOOP
NOP
RET
WARN2S:PUSH PSW
PUSH ACC
MOV R5, #14H ;調(diào)用20次BP,報(bào)警2s
WARN:LCALL BP
DJNZ R5,WARN
NOP
POP ACC
POP PSW
NOP
RET
BP:CLR SPK ;鳴笛子程序
LCALL T100MSD
SETB SPK
NOP
RET
;***************************
;***** 顯示子程序 ********
;***************************
;功能:分五屏幕顯示數(shù)據(jù)，分別是XSA,XSB,XSC,XSD,XSE.代表六種狀態(tài)。
;鎖定狀態(tài)顯示。
XSA:PUSH ACC
PUSH PSW
MOV A, TIMERS1
MOV DPTR, #TAB
MOVC A, @A+DPTR
MOV SBUF, A ;送已經(jīng)輸入密碼的次數(shù)
JNB TI, $
CLR TI
MOV SBUF, #0FEH ;送短線
JNB TI, $
CLR TI
MOV SBUF, #0FEH ;送短線
JNB TI, $
CLR TI ;送F
MOV SBUF, #78H
JNB TI, $
CLR TI
MOV SBUF, #78H
JNB TI, $
CLR TI
MOV SBUF, #11H
JNB TI, $
CLR TI
POP PSW
POP ACC
RET
;成功開鎖狀態(tài)顯示
XSB:PUSH ACC
PUSH PSW
MOV A, TIMERS1
MOV DPTR, #TAB
MOVC A, @A+DPTR
MOV SBUF, A
JNB TI, $
CLR TI
MOV SBUF, #0FEH
JNB TI, $
CLR TI
MOV SBUF, #0FEH
JNB TI, $
CLR TI
MOV SBUF, #10H
JNB TI, $
CLR TI
MOV SBUF, #10H
JNB TI, $
CLR TI
MOV SBUF, #10H
JNB TI, $
CLR TI
POP PSW
POP ACC
RET
;密碼輸入及修改狀態(tài)
XSC:PUSH ACC
PUSH PSW
LCALL KILLXS
SETB RS1 ;切換到第三組寄存器。防止操作數(shù)讀取錯(cuò)誤。
MOV R6, TIMERS
MOV A, R6
SUBB A, #01H
JNC SC0
JZ SC1
SC0:MOV SBUF, #0FEH
JNB TI, $
CLR TI
SC1:MOV A, R6
SUBB A, #02H
JNC SC11
JNZ SC2
SC11:MOV SBUF,#0FEH
JNB TI, $
CLR TI
SC2:MOV A, R6
SUBB A, #03H
JNC SC22
JNZ SC3
SC22:MOV SBUF, #0FEH
JNB TI, $
CLR TI
SC3:MOV A, R6
SUBB A, #04H
JNC SC33
JNZ SC4
SC33:MOV SBUF, #0FEH
JNB TI, $
CLR TI
SC4:MOV A, R6
SUBB A, #05H
JNC SC44
JNZ SC5
SC44:MOV SBUF, #0FEH
JNB TI, $
CLR TI
SC5:MOV A, R6
SUBB A, #06H
JNC SC55
JNZ SC6
SC55:MOV SBUF, #0FEH
JNB TI, $
CLR TI
SC6:MOV A, R6
SUBB A, #07H
JNC SC66
JNZ EXIT_C
SC66:MOV SBUF, #0FEH
JNB TI, $
CLR TI
NOP
NOP
EXIT_C:NOP
CLR RS1
POP PSW
POP ACC
NOP
RET
;密碼輸入錯(cuò)誤的提示
XSD:PUSH ACC
PUSH PSW
MOV SBUF, #98H
JNB TI, $
CLR TI
MOV SBUF, #79H
JNB TI, $
CLR TI
MOV SBUF, #11H
JNB TI, $
CLR TI
MOV SBUF, #79H
JNB TI, $
CLR TI
MOV SBUF, #79H
JNB TI, $
CLR TI
MOV SBUF, #38H
JNB TI, $
CLR TI
POP PSW
POP ACC
RET
;鎖定狀態(tài)顯示
XSE:PUSH ACC
PUSH PSW
MOV SBUF, #0FEH
JNB TI, $
CLR TI
MOV SBUF, #54H
JNB TI, $
CLR TI
MOV SBUF, #39H
JNB TI, $
CLR TI
MOV SBUF, #11H
JNB TI, $
CLR TI
MOV SBUF, #3DH
JNB TI, $
CLR TI
MOV SBUF, #0FEH
JNB TI, $
CLR TI
POP PSW
POP ACC
RET
XSF:PUSH ACC
PUSH PSW
MOV SBUF, #98H
JNB TI, $
CLR TI
MOV SBUF, #38H
JNB TI, $
CLR TI
MOV SBUF, #39H
JNB TI, $
CLR TI
MOV SBUF, #39H
JNB TI, $
CLR TI
MOV SBUF, #3DH ;U
JNB TI, $
CLR TI
MOV SBUF, #98H
JNB TI, $
CLR TI
POP PSW
POP ACC
RET
KILLXS:PUSH ACC
PUSH PSW
MOV R7, #06H
LOOP_XS:MOV SBUF, #0FFH
JNB TI, $
CLR TI
DJNZ R7,LOOP_XS
NOP
POP PSW
POP ACC
RET
TAB: DB 11H,0D7H,32H,92H,0D4H,98H,18H,0D1H,10H,90H ,0FFH
;****************************************************************
;******* 24C02讀寫程序 ×××××××
;****************************************************************
AT_RADE:PUSH PSW
PUSH ACC
MOV R0,#AT1 ;CPU首地址
MOV R6,#06H ;8字節(jié)
MOV R5,#08H ;8位
MOV R7,#00H ;24C02首地址
LCALL READ ;讀數(shù)據(jù)
NOP
NOP
POP ACC
POP PSW
RET
AT_WR:
PUSH PSW
PUSH ACC
MOV R0,#PS1 ;CPU RAM首地址
MOV R6,#06H ;8字節(jié)
MOV R5,#08H ;8 BIT
MOV R7,#00H ;24C02 RAM 首地址
LCALL WRT ;先寫進(jìn)
NOP
NOP
POP ACC
POP PSW
RET
;---------------------
;讀串行器件 R0:RAM的起始地址,R5:位計(jì)數(shù)器,
;R6:讀的字節(jié)數(shù)，R7:讀的起始地址
READ: NOP
NOP
LCALL START0
MOV A,#0A0H
LCALL WRB
LCALL ACK
JB F0,RD_FAIL
MOV A,R7
LCALL WRB
LCALL CHK
JB F0,RD_FAIL
LCALL START0
MOV A,#0A1H
LCALL WRB
LCALL CHK
JB F0,RD_FAIL
RD_N: NOP
NOP
LCALL RDB
MOV @R0,A
DJNZ R6,GO_ACK
LCALL N_ACK
RD_FAIL:NOP
LCALL STOP
MOV A,#0FFH
RET;*************read
GO_ACK: NOP
NOP
DEC R0
LCALL ACK
JMP RD_N
;寫串行器件 R0:RAM的起始地址,R5:位計(jì)數(shù)器,
;R6:寫的字節(jié)數(shù)(頁)，R7:寫的起始地址
WRT: NOP
NOP
LCALL START0
MOV A,#0A0H
LCALL WRBYT
LCALL CHK
JB F0,WR_FAIL
MOV A,R7
LCALL WRBYT
LCALL CHK
JB F0,WR_FAIL
WR_N: NOP
NOP
MOV A,@R0
LCALL WRBYT
LCALL CHK
JB F0,WR_FAIL
DEC R0
DJNZ R6,WR_N
WR_FAIL:NOP
LCALL STOP
MOV A,#0FFH
RET;*********wrt
;--------------------
START0: NOP
NOP
SETB SDA
SETB SCL
NOP
NOP
CLR SDA
NOP
NOP
CLR SCL
NOP
RET
;-------------------
STOP: NOP
NOP
CLR SDA
SETB SCL
NOP
NOP
SETB SDA
NOP
NOP
CLR SCL
NOP
RET
;--------------------
ACK: NOP
NOP
CLR SDA
SETB SCL
NOP
NOP
CLR SCL
SETB SDA
NOP
RET
;--------------------
N_ACK: NOP
NOP
SETB SDA
SETB SCL
NOP
NOP
CLR SCL
CLR SDA
NOP
RET
;--------------------
CHK: NOP
NOP
SETB SDA
NOP
NOP
SETB SCL
NOP
NOP
MOV C,SDA
MOV F0,C
CLR SCL
NOP
NOP
RET
;---------------------
RDB: NOP
NOP
SETB SDA
MOV R5,#8
RD_B: NOP
NOP
CLR SCL
NOP
NOP
SETB SCL
NOP
NOP
MOV C,SDA
RLC A
NOP
NOP
SETB SDA
CLR SCL
DJNZ R5,RD_B
NOP
RET
;一字節(jié)數(shù)據(jù)發(fā)送子程序
WRBYT: MOV R5,#8
WLP: RLC A
JC WR1
CLR SDA
SETB SCL
NOP
NOP
CLR SCL
DJNZ R5,WLP
RET
WR1: SETB SDA
SETB SCL
NOP
NOP
CLR SCL
CLR SDA
DJNZ R5,WLP
RET
;--------------------
WRB: NOP
NOP
MOV R5,#8
WR_B: NOP
NOP
SETB SDA
RLC A
JC WR_1
CLR SDA
NOP
WR_1: SETB SCL
NOP
NOP
CLR SCL
NOP
CLR SDA
NOP
DJNZ R5,WR_B
NOP
RET
;**************************************************************************
;************* 毫秒延時(shí)程序 ***********************
;**************************************************************************
T10MSD:SETB RS0
MOV R4, #12
TM:MOV R3, #128
TM6:DJNZ R3, TM6
DJNZ R4, TM
CLR RS0
RET
T100MSD:MOV R3, #200
D11:MOV R4, #125
D12:DJNZ R4, D12
DJNZ R3, D11
RET
T500MSD:LCALL T100MSD
LCALL T100MSD
LCALL T100MSD
LCALL T100MSD
LCALL T100MSD
NOP
RET
SEC:SETB RS1
MOV R7, #0AH
SEC_LP:LCALL T100MSD
DJNZ R7,SEC_LP
NOP
CLR RS1
RET
END
|
|
66821730(技術(shù)支持)
